Install AppleScriptTask file | Mac Excel Automation

Install AppleScriptTask script file or/and Add-in with AppleScript file

When you follow the link below I show you examples on that page about the new VBA command named AppleScriptTask How to use AppleScriptTask in Mac Office, sometimes it is the only way to get things working on a Mac, all my Mail code examples use for example a AppleScriptTask file.

Seems that some people have problems to copy an AppleScriptTask file in the correct location, so this week I create AppleScript for it to install the file in the correct location to make this easier for them I hope. There is also an example to install an Add-in and one that Install an Add-in and AppleScriptTask file. I not say it is perfect but maybe it give you some ideas.

In the test example below I use a AppleScriptTask file with the script below that you can call in your VBA macros to open the folder you want on your Mac : This is the AppleScriptTask script in the OpenFolder.scpt file

Install AppleScriptTask file with AppleScript file on your Mac

What do you need to do? before you can let people install your AppleScriptTask file in the correct location :

Create a new folder
Copy your AppleScriptTask File in this folder
Copy the install file with the install script below also in this folder
Be sure that the name of the folder is correct in the Install script
Be sure that the name of the AppleScriptTask file is correct in the Install script
Be sure that the name of the Install file is correct in the Install script

You can download an example here that install the file named OpenFolder.scpt in the correct folder for you when you run the Install file inside the folder named 'MyAppleScriptTaskFileFolder''. The folder must be in the Users Download folder, you see that if you download the compressed folder from my website it will automatically uncompressed in your Downloads folder and you can double-click the Install.scpt file in it to open and Run it.

Download example (23-8-2024)

You can test the VBA macro below now to see if it will open the AppleScriptTask folder in Finder

Sub OpenFolderInFinder()
'If you want to easy copy the path of the folder that you want to open in the script then
'Open the folder in Finder and be sure that in the Finder>View menu
'Show Path Bar is on, right click on the folder in the bar and choose copy ... as pathname
'Example below will open the AppleScriptTask folder for Excel in Finder, no need to change the code to test
Dim RunMyScript As String
Dim FolderPath As String

On Error Resume Next
FolderPath = MacScript("return POSIX path of (path to home folder) as string")
FolderPath = Replace(FolderPath, "/Library/Containers/com.microsoft.Excel/Data", "") & "Library/Application Scripts/com.microsoft.Excel/"

'Other examples are
'FolderPath = MacScript("return POSIX path of (path to Desktop) as string")

'Also Desktop but you must enter the path yourself
'FolderPath = "/Users/rondebruin/Desktop"

'Example to open a folder named Ron that is on the Desktop
'FolderPath = MacScript("return POSIX path of (path to Desktop) as string") & "Ron"

RunMyScript = AppleScriptTask("OpenFolder.scpt", "OpenFolderInFinder", FolderPath)
If RunMyScript = "Error" Then
    MsgBox "Wrong folder path"
End If
End Sub

And below you see the Script that is in the Install.scpt file.
Note: See the 3 lines in the script that you must change to your own situation if you want to use it.

--Ron de Bruin, 23-Aug-2024
--https://macexcel.com

--Installation script to install an AppleScriptTask file. Create a folder with your AppleScriptTask file and this installation script
--in it and make sure this folder get into the Downloads folder of the user, this happens automatically when the user download
--it in a zip file from your website for example. There are only 3 lines you need to change in the script before you can install
--your own AppleScriptTask file, the name of the folder, name of the AppleScriptTask file and name of this install script 

--Note: The script will delete the existing file first if it exist before it paste the new one.
--Note: You can also save this script as an Application file, the user must give permission to run the script but not see the script.

--When you run this script It will copy the AppleScriptTask file from the 'FolderName' folder in the Downloads folder inside the 'ScriptFolderExcel' folder

display dialog "First close Excel and press OK to install the AppleScriptTask file in the correct location." buttons {"OK", "Cancel"} default button "OK"
if the button returned of the result is "Ok" then
	
	--***This are the only 3 lines of the script that you must change one time***--
	
	--Name of the folder with AppleScriptTask file and this install script file inside the Downloads folder of your Mac
	set FolderName to "MyAppleScriptTaskFileFolder"
	--Name of the AppleScriptTask file in the folder
	set AppleScriptTaskFile to "OpenFolder.scpt"
	--Name of the install file inside this folder
	set InstallScriptfileName to "Install.scpt"
	
	tell application "Finder"
		set Source to (path to downloads folder as text) & FolderName & ":"
		
		if (exists folder Source) then
			--Part to install the AppleScriptTask file
			set ScriptFolder to (path to home folder as text) & "Library:Application Scripts:"
			set ScriptFolderExcel to (path to home folder as text) & "Library:Application Scripts:com.microsoft.Excel:"
			
			if not (exists folder ScriptFolderExcel) then
				make new folder in ScriptFolder with properties {name:"com.microsoft.Excel"}
			end if
			
			if exists file (ScriptFolderExcel & AppleScriptTaskFile) then
				delete ScriptFolderExcel & AppleScriptTaskFile
			end if
			copy file (Source & AppleScriptTaskFile) to folder ScriptFolderExcel
			
			display dialog "The " & AppleScriptTaskFile & " is now in the correct location and you can call it now with the VBA AppleScriptTask function in your code." buttons {"OK"} default button "OK"
		else
			display dialog "Can't find the " & FolderName & " folder inside the Downloads folder." buttons {"OK"} default button "OK"
		end if
	end tell
end if

Tip: You can also save the Install.scpt as Application file (.app), this way the user not see the script.

Install Add-in with AppleScript file on your Mac

The example script below will install an Add-in in Excel in the correct folder on your Mac, it will work almost the same as the first example. Instead of 3 things that you must change there is now a new option to keep the folder with for example help and example files for the add-in in your add-ins folder if you want, read the info in the script.

--Ron de Bruin, 23-Aug-2024
--https://macexcel.com

--Installation script to install an add-in. Create a folder with your add-in and this installation script and possibly help
--and sample files in it and make sure this folder get into the Downloads folder of the user, this happens automatically 
--when the user download it in a zip file from your website for example. There are only 4 lines you need to change in the 
--script before you can use it to install your own add-in, the name of the folder, name of the add-in, name of this
--install script and use KeepFolder to say if you want to keep the folder yes or no.
--Note: The script will delete the existing folder/files first if they exist before it paste the new ones.
--Note: You can also save this script as an Application file, the user must give permission to run the script but not see the script.

--It will create a empty folder with the name 'FolderName' in the Add-ins folder
--Copy every file from the 'FolderName' folder in the Downloads folder inside this folder
--Move the add-in with the name 'AddInName' from the folder inside the root of the Add-ins folder
--Delete the whole folder from the Add-ins folder or only the script file with the name 'InstallScriptfileName'

display dialog "First close Excel and press OK to install the add-in and AppleScriptTask file in the correct location." buttons {"OK", "Cancel"} default button "OK"
if the button returned of the result is "Ok" then
	--***This are the only 4 lines of the script that you must change***--
	
	--Name of the folder with the add-in and this install script file and possibly help and sample files 
	set FolderName to "MacInsertSheetTemplates"
	--Name of the add-in file inside this folder
	set AddInName to "RDBMacInsertsheet.xlam"
	--Name of the install file inside this folder
	set InstallScriptfileName to "Install2.scpt"
	--set to 'true' if you want to keep the folder in the Add-ins folder with for example help or example files
	set KeepFolder to false
	
	--Do not change the script lines below
	tell application "Finder"
		set Source to (path to downloads folder as text) & FolderName
		
		if (exists folder Source) then
			--Part to install the add-in
			set AddinFolder to (path to home folder as text) & "Library:Group Containers:UBF8T346G9.Office:User Content.localized:Add-Ins.localized:"
			set DestinationFolder to (path to home folder as text) & "Library:Group Containers:UBF8T346G9.Office:User Content.localized:Add-Ins.localized:" & FolderName & ":"
			
			if (exists folder DestinationFolder) then
				delete DestinationFolder
			end if
			
			if not (exists folder DestinationFolder) then
				make new folder in AddinFolder with properties {name:FolderName}
			end if
			
			duplicate every item in the folder Source to DestinationFolder
			
			if exists file (AddinFolder & AddInName) then
				delete AddinFolder & AddInName
			end if
			move DestinationFolder & AddInName to folder AddinFolder
			
			if KeepFolder is true then
				delete DestinationFolder & InstallScriptfileName
			else
				delete DestinationFolder
			end if
			
			display dialog "Open Excel use Tools>Add-Ins... to add a checkmark before " & AddInName & " so it will always load when you open Excel." buttons {"OK"} default button "OK"
		else
			display dialog "Can't find the " & FolderName & " folder inside the Downloads folder." buttons {"OK"} default button "OK"
		end if
	end tell
end if

Install Add-in and AppleScriptTask file with AppleScript file on your Mac

The example script below will install an Add-in in Excel in the correct folder on your Mac and also an AppleScriptTask file in the correct folder, it will work almost the same as the Add-in example, there is only a new row in this script where you must fill in the AppleTaskScript file name. And also the option to keep the folder with for example your help and example files for the add-in in your add-ins folder if you want, read the info in the script.

--Ron de Bruin, 23-Aug-2024
--https://macexcel.com

--Installation script to install an add-in and AppleScriptTask file. Create a folder with your add-in, AppleScriptTask file and this installation script
--and possibly help and sample files in it and make sure this folder get into the Downloads folder of the user, this happens automatically 
--when the user download it in a zip file from your website for example. There are only 5 lines you need to change in the script before
--you can use it to install your own add-in and AppleScriptTask file, the name of the folder, name of the add-in, name of the AppleScriptTask 
--file, name of this install script and use KeepFolder to say if you want to keep the folder yes or no.
--Note: The script will delete the existing folder/files first if they exist before it paste the new ones.
--Note: You can also save this script as an Application file, the user must give permission to run the script but not see the script.

--It will create a empty folder with the name 'FolderName' in the Add-ins folder
--Copy every file from the 'FolderName' folder in the Downloads folder inside this folder
--Move the add-in with the name 'AddInName' from the folder inside the root of the Add-ins folder
--Delete the whole folder from the Add-ins folder or only the script file with the name 'InstallScriptfileName'

display dialog "First close Excel and press OK to install the add-in and AppleScriptTask file in the correct location." buttons {"OK", "Cancel"} default button "OK"
if the button returned of the result is "Ok" then
	
	--***This are the only 5 lines of the script that you must change one time***--
	
	--Name of the folder with add-in and AppleScriptTask file and this install script file and example
	--and help files inside the Downloads folder of your Mac
	set FolderName to "MyProjectFolder"
	--Name of the add-in file inside the folder
	set AddInName to "MyAddin.xlam"
	--Name of the AppleScriptTask file in the folder
	set AppleScriptTaskFile to "MyAppleScriptTaskScript.scpt"
	--Name of the install file inside this folder
	set InstallScriptfileName to "Install3.scpt"
	--set to 'true' if you want to keep the folder in the Add-ins folder with for example help or example files
	set KeepFolder to true
	
	tell application "Finder"
		set Source to (path to downloads folder as text) & FolderName
		
		if (exists folder Source) then
			--Part to install the add-in
			set AddinFolder to (path to home folder as text) & "Library:Group Containers:UBF8T346G9.Office:User Content.localized:Add-Ins.localized:"
			set DestinationFolder to (path to home folder as text) & "Library:Group Containers:UBF8T346G9.Office:User Content.localized:Add-Ins.localized:" & FolderName & ":"
			
			if (exists folder DestinationFolder) then
				delete DestinationFolder
			end if
			
			if not (exists folder DestinationFolder) then
				make new folder in AddinFolder with properties {name:FolderName}
			end if
			
			duplicate every item in the folder Source to DestinationFolder
			
			if exists file (AddinFolder & AddInName) then
				delete AddinFolder & AddInName
			end if
			
			move DestinationFolder & AddInName to folder AddinFolder
			
			--Part to install the AppleScriptTask file
			set ScriptFolder to (path to home folder as text) & "Library:Application Scripts:"
			set ScriptFolderExcel to (path to home folder as text) & "Library:Application Scripts:com.microsoft.Excel:"
			
			if not (exists folder ScriptFolderExcel) then
				make new folder in ScriptFolder with properties {name:"com.microsoft.Excel"}
			end if
			
			if exists file (ScriptFolderExcel & AppleScriptTaskFile) then
				delete ScriptFolderExcel & AppleScriptTaskFile
			end if
			move DestinationFolder & AppleScriptTaskFile to folder ScriptFolderExcel
			
			if KeepFolder is true then
				delete DestinationFolder & InstallScriptfileName
			else
				delete DestinationFolder
			end if
			
			display dialog "Open Excel use Tools>Add-Ins... to add a checkmark before " & AddInName & " so it will always load when you open Excel." buttons {"OK"} default button "OK"
		else
			display dialog "Can't find the " & FolderName & " folder inside the Downloads folder." buttons {"OK"} default button "OK"
		end if
	end tell
end if